C
C     **********************************************
C     **                                          **
C     **            経済前提の読み込み            **
C     **                                          **
C     **********************************************
C
C
      SUBROUTINE     ECON
C
C
      IMPLICIT INTEGER(A-Z)
      INCLUDE 'seps.inc'
C
      COMMON /INECON/JH_KAITE,KOUJOR
      REAL*8 JH_KAITE(5:ECEDY),KOUJOR(5:ECEDY)
C
      REAL*8 DUM
C
      REAL*8 CI_KIJUN,TAMARI_CI
      REAL*8 HHD,CID
C
C     本来水準の改定率
      REAL*8 KAITE_HH,KAITE_HP,KAITE_CI
      REAL*8 KAITE_HHRD,KAITE_HPRD,KAITE_CIRD
C
      REAL*8 ID_HH_JUZEN(ECSTY:ECEDY),ID_HH_HON0(ECSTY:ECEDY,63:115)
      REAL*8 ID_HH_HONJU8W(ECSTY:ECEDY,63:115)
      REAL*8 ID_HH_TOKU(ECSTY:ECEDY,63:115)
      REAL*8 ID_HH_SIKU(ECSTY:ECEDY,63:115)
      REAL*8 ARV_HH(ECSTY:ECEDY,63:115)
C
      REAL*8 IDR_HP_HON(ECSTY:ECEDY,63:115)
      REAL*8 IDG_HP_HON8W(ECSTY:ECEDY,63:115)
      REAL*8 IDR_HP_TOKU(ECSTY:ECEDY,63:115)
      REAL*8 IDG_HP_TOKU(ECSTY:ECEDY,63:115)
      REAL*8 IDG_HP_SIKU(ECSTY:ECEDY,63:115)
      REAL*8 ARV_HP(ECSTY:ECEDY,63:115)
C
      REAL*8 RV(ECSTY:ECEDY,23)
      DIMENSION SAME(15:23)
      DATA SAME / 14, 14, 14,  6,  4,  5,  5, 13,  4 /
C
C
C     変数の初期化
C
      DO K=ECSTY,ECEDY
        ID_HH_JUZEN(K)=0.0D0
        CI0(K)=0.0D0
        DO X=63,115
          ID_HH_HON0(K,X)=0.0D0
          ID_HH_HONJU8W(K,X)=0.0D0
          ID_HH_TOKU(K,X)=0.0D0
          ID_HH_SIKU(K,X)=0.0D0
          ARV_HH(K,X)=0.0D0
C
          IDR_HP_HON(K,X)=0.0D0
          IDG_HP_HON8W(K,X)=0.0D0
          IDR_HP_TOKU(K,X)=0.0D0
          IDG_HP_TOKU(K,X)=0.0D0
          IDG_HP_SIKU(K,X)=0.0D0
          ARV_HP(K,X)=0.0D0
        END DO
      END DO
C
C
C     推計年度の読み込み
C
      DO 1000 K=1,KE+5
C
        READ(20,*,END=9999) KK,RI(K),DUM,DUM,DUM,H(K),CI0(K)
        IF(K.NE.KK) THEN
          WRITE(6,*) '経済前提ファイルの読込み年度が違います！(econ.f)'
          STOP
        END IF
C
        RI(K) =RI(K) /1.0D2
        H(K)  =H(K)  /1.0D2
        CI0(K)=CI0(K)/1.0D2
C
        GO TO 1100
C
 9999   CONTINUE
        RI(K) =RI(K-1)
        H(K)  =H(K-1)
        CI0(K)=CI0(K-1)
C
 1100 CONTINUE
C
        IF(K.EQ.1) CI0(K)=-0.70D-2
C
C
 1000 CONTINUE
C
      WRITE(6,8000) RI(KE)*1.0D2,H(KE)*1.0D2,CI0(KE)*1.0D2
C
C     K=4(H16)の指数を初期化
      TAMARI_CI = -1.7D-2
C
C     比例従前水準
      ID_HH_JUZEN(4)=0.986D0
C     比例本来
      ID_HH_HON0(4,67)=0.990D0
      ID_HH_HON0(4,68)=0.982D0
      ID_HH_HON0(4,69)=0.975D0
      ID_HH_HON0(4,70)=0.971D0
      ID_HH_HON0(4,71)=0.971D0
      ID_HH_HON0(4,72)=0.971D0
      ID_HH_HON0(4,73)=0.971D0*1.064D0/1.069D0
      ID_HH_HON0(4,74)=0.971D0*1.041D0/1.069D0
      ID_HH_HON0(4,75)=0.971D0*1.031D0/1.069D0
C     比例本来（従前、８割丈比べ後）
      ID_HH_HONJU8W(4,67)=MAX(MAX(ID_HH_JUZEN(4),ID_HH_HON0(4,67)),
     &                        ID_HH_HON0(4,67)*0.8D0               )
C     比例特例水準と実際の支給水準
      ID_HH_TOKU(4,67)=1.003D0
      ID_HH_SIKU(4,67)=MAX(ID_HH_HONJU8W(4,67),ID_HH_TOKU(4,67))
C
C     基礎本来率
      IDR_HP_HON(4,67)=1.000D0
C     基礎本来額（８割丈比べ後）
      IDG_HP_HON8W(4,67)=7809D0
C     基礎特例率と額
      IDR_HP_TOKU(4,67)=0.988D0
      IDG_HP_TOKU(4,67)=ANINT(IDR_HP_TOKU(4,67)*8042D0)
C     基礎支給額
      IDG_HP_SIKU(4,67)=MAX(IDG_HP_HON8W(4,67),IDG_HP_TOKU(4,67))
C
C     68歳以降の指数の代入
      DO 2000 X=68,115
        IF(X.GE.76) ID_HH_HON0(4,X)=ID_HH_HON0(4,75)
        ID_HH_HONJU8W(4,X)=MAX(MAX(ID_HH_JUZEN(4),ID_HH_HON0(4,X)),
     &                         ID_HH_HON0(4,67)*0.8D0              )
        ID_HH_TOKU(4,X)=ID_HH_TOKU(4,67)
        ID_HH_SIKU(4,X)=MAX(ID_HH_HONJU8W(4,X),ID_HH_TOKU(4,X))
C
        IDR_HP_HON(4,X)=IDR_HP_HON(4,67)
        IDG_HP_HON8W(4,X)=IDG_HP_HON8W(4,67)
        IDR_HP_TOKU(4,X)=IDR_HP_TOKU(4,67)
        IDG_HP_TOKU(4,X)=IDG_HP_TOKU(4,67)
        IDG_HP_SIKU(4,X)=IDG_HP_SIKU(4,67)
 2000 CONTINUE
C
C     特例〜従前額保証用再評価率の設定
      JZ_SHK(4)=ANINT( 0.917D0 / 0.990D0 *1.0D3 ) / 1.0D3
C
C     平成６年度からの可処分所得割合の変化率
C   （平成17(2005)年度以降は後で）
      DIR(4)=0.980D0
C
C
C     K=5(H17)以降の処理
C
      CI_KIJUN=1.0D0
C     実質賃金と可処分所得割合変化率の設定
      CALL JITSUCHIN_KASHOBUN
C
      DO 2100 K=5,KE+5
C       2005年度以降の年金改定率作成（本来分）
        KAITE_CI=CI0(K-1)
        KAITE_HH=(1.0D0+KAITE_CI)*JH_KAITE(K)*KOUJOR(K)-1.0D0
C
        KAITE_CIRD=ANINT(CI0(K-1)*1.0D3)/1.0D3
        KAITE_HHRD=(1.0D0+KAITE_CIRD)*ANINT(JH_KAITE(K)*1.0D3)/1.0D3
     &            *ANINT(KOUJOR(K)*1.0D3)/1.0D3-1.0D0
        KAITE_HHRD=ANINT(KAITE_HHRD*1.0D3)/1.0D3
C
C       逆転防止処理
        HHD = KAITE_HH
        CID = KAITE_CI
        IF(HHD.LT.CID .AND. HHD.LT.0.0D0) KAITE_HH=MIN(CID,0.0D0)
        IF(HHD.LT.CID .AND. CID.GT.0.0D0) KAITE_CI=MAX(HHD,0.0D0)
C
        IF(TAMARI_CI.GE.0.0D0) THEN
C         特例〜従前額保証用再評価率の設定
          IF(HHD.LT.CID .AND. HHD.LT.0.0D0) THEN
            JZ_SHK(K)=JZ_SHK(K-1)/(1.0D0+CI0(K-1))
          ELSE
            JZ_SHK(K)=JZ_SHK(K-1)/(1.0D0+CI0(K-1))/JH_KAITE(K)
          END IF
        END IF
C
        HHD = KAITE_HHRD
        CID = KAITE_CIRD
        IF(HHD.LT.CID .AND. HHD.LT.0.0D0) KAITE_HHRD=MIN(CID,0.0D0)
        IF(HHD.LT.CID .AND. CID.GT.0.0D0) KAITE_CIRD=MAX(HHD,0.0D0)
C
        IF(TAMARI_CI.LT.0.0D0) THEN
C         特例〜従前額保証用再評価率の設定
          IF(HHD.LT.CID .AND. HHD.LT.0.0D0) THEN
            JZ_SHK(K)=ANINT( JZ_SHK(K-1)/(1.0D0+CI0(K-1)) *1.0D3 )
     &                                                           /1.0D3
          ELSE
            JZ_SHK(K)=ANINT( JZ_SHK(K-1)/(1.0D0+CI0(K-1))
     &                      /(ANINT(JH_KAITE(K)*1.0D3 )/1.0D3) *1.0D3 )
     &                                                           /1.0D3
          END IF
        END IF
C
C       新裁基礎の代入
        IF(K.GE.7) THEN
          KAITE_HP  =KAITE_HH
          KAITE_HPRD=KAITE_HHRD
        ELSE
          KAITE_HP  =KAITE_CI
          KAITE_HPRD=KAITE_CIRD
        END IF
C
C       特例水準の改定（従来方式）
        CI_KIJUN=ANINT(CI_KIJUN*(1.0D0+CI0(K-1))*1.0D3)/1.0D3
C
        IF(CI_KIJUN.LT.1.0D0) THEN
          CID=CI_KIJUN-1.0D0
          CI_KIJUN=1.0D0
        ELSE
          CID=0.0D0
        END IF
        HHD=CID
        IF(FLG_KAISHO.EQ.2) THEN
          IF(K.EQ.13 .OR. K.EQ.14) THEN
            IF(K.EQ.13 .AND.
     &         (CID.NE.KAITE_HHRD .OR. CID.NE.KAITE_CIRD)) THEN
              WRITE(6,*) 'H25.10の特例解消幅が△1.0％ではありません。'
              STOP
            END IF
            HHD=MIN(1.0D0,ANINT((1.0D0+KAITE_HHRD)*0.99D0*1.0D3)/1.0D3)
     &          -1.0D0
            CID=MIN(1.0D0,ANINT((1.0D0+KAITE_CIRD)*0.99D0*1.0D3)/1.0D3)
     &          -1.0D0
          ELSE IF(K.GE.15) THEN
            HHD=-1.0D0
            CID=-1.0D0
          END IF
        END IF
C
C       指数等の改定
        IF(TAMARI_CI.LT.0.0D0) THEN
C         従前の指数
          ID_HH_JUZEN(K)=ANINT( ID_HH_JUZEN(K-1)
     &                         *(1.0D0+KAITE_CIRD)*1.0D4 )/1.0D4
C         比例本来の指数
          ID_HH_HON0(K,67)=ANINT( ID_HH_HON0(K-1,67)
     &                           *(1.0D0+KAITE_HHRD)*1.0D4 )/1.0D4
          DO 2110 X=68,115
            ID_HH_HON0(K,X)=ANINT( ID_HH_HON0(K-1,X-1)
     &                            *(1.0D0+KAITE_CIRD)*1.0D4 )/1.0D4
 2110     CONTINUE
C         2005年度以降の可処分所得割合の変化率
          DIR(K)=ANINT( DIR(K-1)*ANINT(KOUJOR(K)*1.0D3)/1.0D3
     &                                                *1.0D3 ) / 1.0D3
        ELSE
C         従前の指数
          ID_HH_JUZEN(K)=ID_HH_JUZEN(K-1)*(1.0D0+KAITE_CI)
C         比例本来の指数
          ID_HH_HON0(K,67)=ID_HH_HON0(K-1,67)*(1.0D0+KAITE_HH)
          DO 2120 X=68,115
            ID_HH_HON0(K,X)=ID_HH_HON0(K-1,X-1)*(1.0D0+KAITE_CI)
 2120     CONTINUE
C         2005年度以降の可処分所得割合の変化率
          DIR(K)=DIR(K-1)*KOUJOR(K)
        END IF
C
C       他の指数（67歳）
C
C       比例本来の指数（８割、従前丈比べ後）
        ID_HH_HONJU8W(K,67)=MAX(MAX(ID_HH_JUZEN(K),ID_HH_HON0(K,67)),
     &                          ID_HH_HON0(K,67)*0.8D0               )
C       比例特例水準
        ID_HH_TOKU(K,67)=ANINT( ID_HH_TOKU(K-1,67)*(1.0D0+HHD)
     &                                                 *1.0D4 )/1.0D4
        IF(K.EQ.6) ID_HH_TOKU(K,67)=0.9999D0
C
C       比例支給水準及び比例改定率
        ID_HH_SIKU(K,67)=MAX(ID_HH_HONJU8W(K,67),ID_HH_TOKU(K,67))
        IF(ID_HH_HONJU8W(K,67).LT.ID_HH_TOKU(K,67)) THEN
          ARV_HH(K,67)=1.0D0+HHD
        ELSE
          ARV_HH(K,67)=ID_HH_SIKU(K,67)/ID_HH_SIKU(K-1,67)
        END IF
C
C       基礎本来率と基礎本来額
        IF(IDG_HP_HON8W(K-1,67).LT.IDG_HP_TOKU(K-1,67)) THEN
          IDR_HP_HON(K,67)=ANINT( IDR_HP_HON(K-1,67)*(1.0D0+KAITE_HPRD)
     &                                                    *1.0D3 )/1.0D3
          IDG_HP_HON8W(K,67)=ANINT( IDR_HP_HON(K,67)*7809D0 )
        ELSE
          IDR_HP_HON(K,67)=IDR_HP_HON(K-1,67)*(1.0D0+KAITE_HP)
          IDG_HP_HON8W(K,67)=IDG_HP_HON8W(K-1,67)*(1.0D0+KAITE_HP)
        END IF
        IDR_HP_TOKU(K,67)=ANINT( IDR_HP_TOKU(K-1,67)*(1.0D0+HHD)
     &                                                    *1.0D3 )/1.0D3
        IDG_HP_TOKU(K,67)=ANINT( IDR_HP_TOKU(K,67)*8042D0 )
C
C       基礎支給額及び基礎改定率
        IDG_HP_SIKU(K,67)=MAX(IDG_HP_HON8W(K,67),IDG_HP_TOKU(K,67))
        IF(IDG_HP_HON8W(K,67).LT.IDG_HP_TOKU(K,67)) THEN
          ARV_HP(K,67)=1.0D0+HHD
        ELSE
          ARV_HP(K,67)=IDG_HP_SIKU(K,67)/IDG_HP_SIKU(K-1,67)
        END IF
C
C       他の指数（68歳以上）
        DO 2130 X=68,115
C         比例本来の指数（８割、従前丈比べ後）
          ID_HH_HONJU8W(K,X)=MAX(MAX(ID_HH_JUZEN(K),ID_HH_HON0(K,X)),
     &                           ID_HH_HON0(K,67)*0.8D0              )
C         比例特例水準
          ID_HH_TOKU(K,X)=ANINT( ID_HH_TOKU(K-1,X-1)*(1.0D0+CID)
     &                                                    *1.0D4 )/1.0D4
          IF(K.EQ.6) ID_HH_TOKU(K,X)=0.9999D0
C
C         比例支給水準及び比例改定率
          ID_HH_SIKU(K,X)=MAX(ID_HH_HONJU8W(K,X),ID_HH_TOKU(K,X))
          IF(ID_HH_HONJU8W(K,X).LT.ID_HH_TOKU(K,X)) THEN
            ARV_HH(K,X)=1.0D0+CID
          ELSE
            ARV_HH(K,X)=ID_HH_SIKU(K,X)/ID_HH_SIKU(K-1,X-1)
          END IF
C
C         基礎本来率と基礎本来額
          IF(IDG_HP_HON8W(K-1,X-1).LT.IDG_HP_TOKU(K-1,X-1)) THEN
            IDR_HP_HON(K,X)=ANINT( IDR_HP_HON(K-1,X-1)
     &                            *(1.0D0+KAITE_CIRD)*1.0D3 )/1.0D3
            IDG_HP_HON8W(K,X)=ANINT( MAX(IDR_HP_HON(K,X),
     &                                   IDR_HP_HON(K,67)*0.8D0)
     &                                                  *7809D0 )
          ELSE
            IDR_HP_HON(K,X)=IDR_HP_HON(K-1,X-1)*(1.0D0+KAITE_CI)
            IDG_HP_HON8W(K,X)=MAX( IDG_HP_HON8W(K,67)*0.8D0,
     &                          IDG_HP_HON8W(K-1,X-1)*(1.0D0+KAITE_CI) )
          END IF
          IDR_HP_TOKU(K,X)=ANINT( IDR_HP_TOKU(K-1,X-1)*(1.0D0+CID)
     &                                                    *1.0D3 )/1.0D3
          IDG_HP_TOKU(K,X)=ANINT( IDR_HP_TOKU(K,X)*8042D0 )
C
C         基礎支給額及び基礎改定率
          IDG_HP_SIKU(K,X)=MAX(IDG_HP_HON8W(K,X),IDG_HP_TOKU(K,X))
          IF(IDG_HP_HON8W(K,X).LT.IDG_HP_TOKU(K,X)) THEN
            ARV_HP(K,X)=1.0D0+CID
          ELSE
            ARV_HP(K,X)=IDG_HP_SIKU(K,X)/IDG_HP_SIKU(K-1,X-1)
          END IF
 2130   CONTINUE
C
C       その他の変数の設定
        IF(TAMARI_CI.LT.0.0D0) THEN
          HH(K)=KAITE_HHRD
          CI(K)=KAITE_CIRD
        ELSE
          HH(K)=KAITE_HH
          CI(K)=KAITE_CI
        END IF
C
        IF(ID_HH_JUZEN(K).LT.ID_HH_TOKU(K,67)) THEN
          CI2(K,67)=HHD
        ELSE IF(ID_HH_JUZEN(K-1).LT.ID_HH_TOKU(K-1,67)) THEN
          CI2(K,67)=ID_HH_JUZEN(K)/ID_HH_TOKU(K-1,67) - 1.0D0
        ELSE
          CI2(K,67)=CI(K)
        END IF
        DO 2140 X=68,115
          IF(ID_HH_JUZEN(K).LT.ID_HH_TOKU(K,X)) THEN
            CI2(K,X)=CID
          ELSE IF(ID_HH_JUZEN(K-1).LT.ID_HH_TOKU(K-1,X-1)) THEN
            CI2(K,X)=ID_HH_JUZEN(K)/ID_HH_TOKU(K-1,X-1) - 1.0D0
          ELSE
            CI2(K,X)=CI(K)
          END IF
 2140   CONTINUE
C
        IF(IDG_HP_HON8W(K-1,67).LT.IDG_HP_TOKU(K-1,67)) THEN
          HP2(K,67)=ARV_HP(K,67)-1.0D0
        ELSE
          HP2(K,67)=KAITE_HP
        END IF
        DO 2150 X=68,115
          IF(IDG_HP_HON8W(K-1,X-1).LT.IDG_HP_TOKU(K-1,X-1)) THEN
            HP2(K,X)=ARV_HP(K,X)-1.0D0
          ELSE
            HP2(K,X)=KAITE_CI
          END IF
 2150   CONTINUE
C
        TAMARI_CI=ANINT( (TAMARI_CI+KAITE_CIRD-CID)*1.0D3 )/1.0D3
C
 2100 CONTINUE
C
C
C     2004年度以前の設定
      HH2(-1)=0.4D-2
      HH2(0) =0.7D-2
      HH2(1) =0.8D-2
      DO 4000 K=1,4
        CI(K)=0.0D0
        IF(K.EQ.3 .OR. K.EQ.4) CI(K)=CI0(K-1)
        DO 4010 X=67,115
          CI2(K,X)=CI(K)
          HP2(K,X)=CI(K)
 4010   CONTINUE
 4000 CONTINUE
C
C     給付改定率(裁定前)／(裁定後)
C
      DO 5000 J=1,23
        DO 5200 K=1,KE
          IF(J.LE.14 .AND. J.NE.13) THEN
            IF(K.LE.3) THEN
              RV(K,J)=CI(K)
              IF(K.EQ.1 .OR. K.EQ.2) RV(K,J)=0.0D0
            ELSE IF(K.EQ.4) THEN
              IF(J.EQ.1 .OR. J.EQ.10) THEN
                RV(K,J)=(1.0D0+CI0(3))*
     &                   ANINT( (1.0D0+HH2(-1))
     &                         *(1.0D0+HH2(0) )
     &                         *(1.0D0+HH2(1) ) *1.0D3 ) / 1.0D3
                RV(K,J)=ANINT( RV(K,J)*1.0D3 )/1.0D3 - 1.0D0
              ELSE
                RV(K,J)=HP2(K,67)
              END IF
            ELSE
              IF(J.EQ.1 .OR. J.EQ.10) THEN
                RV(K,J)=HH(K)
              ELSE
                RV(K,J)=HP2(K,67)
              END IF
            END IF
          ELSE IF(J.EQ.13) THEN
            RV(K,J)=0.0D0
          ELSE
            RV(K,J)=RV(K,SAME(J))
          END IF
C
 5200   CONTINUE
 5000 CONTINUE
C
C     年金改定率及び標準報酬上昇率累計値
C
      AD(KIJUN)=1.0D0
      DO 6100 K=KIJUN+1,KE
        AD(K)=AD(K-1)*(1.0D0+H(K))
 6100 CONTINUE
      AD2(4)=0.988D0
      DO 6200 K=5,KIJUN
        AD2(K)=AD2(K-1)*(1.0D0+HP2(K,67))
 6200 CONTINUE
      DO 6300 J=1,23
        BD(KIJUN,J)=1.0D0
        DO 6400 K=KIJUN+1,KE
          BD(K,J)=BD(K-1,J)*(1.0D0+RV(K,J))
 6400   CONTINUE
 6300 CONTINUE
C
C
C     年金改定率の出力
C
      IF(KAITE.EQ.1 .AND.
     &   ((SEIDN.LE.6 .AND. SEIDN.NE.0) .OR. 
     &    ((SEIDN.EQ.0 .OR. SEIDN.GE.7) .AND. PSEID.EQ.0))) THEN
        DO 7000 K=5, FLKE
     	  IF(K.GE.5 .AND. K.LE.KE) THEN
            WRITE(23,8400) K,(ARV_HH(K,X),X=67,115)
            WRITE(22,8400) K,(ARV_HP(K,X),X=67,115)
          ELSE
            WRITE(23,8400) K,(0.0D0,X=67,115)
            WRITE(22,8400) K,(0.0D0,X=67,115)
          END IF
 7000   CONTINUE
      END IF
C
      WRITE(01,8100)
      WRITE(01,8200)
      DO 7400 K=1,KE
        WRITE(01,8300) K,RI(K),H(K),CI(K),RV(K,1),
     &                 RV(K,4),RV(K,14),CI2(K,67)
 7400 CONTINUE
C
C
 8000 FORMAT(1H ,'利回りは',F5.2,'％','  賃金は',F5.2,'％','  物価は'
     &       ,F5.2,'％')
 8100 FORMAT('経済的要素')
 8200 FORMAT('年度,利回り,賃金,物価,改定率(比例),',
     &       '改定率(加給),改定率(基礎),改定率(物価)')
 8300 FORMAT(I5,',',7(F8.5,','))
 8400 FORMAT(I3,',',49(F17.14,','))
C
C
      RETURN
C
      END
C
C
C     **********************************************
C     **                                          **
C     **   実質賃金と可処分所得割合変化率の設定   **
C     **      （名目手取り賃金改定率算出用）      **
C     **                                          **
C     **********************************************
C
C
      SUBROUTINE     JITSUCHIN_KASHOBUN
C
C
      IMPLICIT INTEGER(A-Z)
      INCLUDE 'seps.inc'
C
      COMMON /INECON/JH_KAITE,KOUJOR
      REAL*8 JH_KAITE(5:ECEDY),KOUJOR(5:ECEDY)
      REAL*8 PREMA(3:ECEDY)
C
C
C     実質賃金変動率（３年平均）の設定
      DO 1000 K=5,KE+5
        JH_KAITE(K)=( ((1.0D0+H(K-4))*(1.0D0+H(K-3))
     &               *(1.0D0+H(K-2))) / ((1.0D0+CI0(K-4))
     &               *(1.0D0+CI0(K-3))*(1.0D0+CI0(K-2))) )
     &               **(1.0D0/3.0D0)
 1000 CONTINUE
C
C
C     可処分所得割合変化率の設定
      PREMA(3)=13.58D-2
      DO 2000 K=4,KE
        PREMA(K)=PREMA(K-1)+0.354D-2
        IF(PREMA(K).GT.18.3D-2) PREMA(K)=18.3D-2
 2000 CONTINUE
C
      DO 3000 K=5,KE+5
        IF(K.LE.6 .OR. K.GE.KE+1) THEN
          KOUJOR(K)=1.0D0
        ELSE
          KOUJOR(K)=(0.910D0-PREMA(K-3)/2.0D0)
     &             /(0.910D0-PREMA(K-4)/2.0D0)
        END IF
C
 3000 CONTINUE
C
C
      RETURN
C
      END
C
