C
C     **********************************************
C     **                                          **
C     **            基礎率をインプット            **
C     **                                          **
C     **********************************************
C
      SUBROUTINE      KISO
C
C
      IMPLICIT INTEGER (A-Z)
      INCLUDE 'seps.inc'
C
      COMMON /S/ S,S2
      COMMON /K/ K
C
      REAL*8 BETA(STTY-4:ENDY,0:115)
      REAL*8 TMP,KDC,KDCTMP
      REAL*8 QPR(2),RDS(2),RDSP1(2),RDSP2(2),RDSP3(2)
C
      CHARACTER*5  NENSYU
      CHARACTER*20 DUM,DUM2
C
      READ(10,*) DUM
      READ(10,*) DUM,SYU,DUM
      DUM2 = DUM
      DUM  = DUM2
C
      IF(SYU.NE.S) THEN
        WRITE(6,*) '基礎率の種別が違います  S  ',SYU
        STOP
      END IF
C
      IF(S2.NE.2) SS=1
      IF(S2.EQ.2) SS=2
C
C --------------------------------------------------------------------
C     Ｕ（Ｋ，Ｘ，０）  総脱退力
C                 １    生存脱退力
C                 ２    障害脱退力
C                 ３    死亡脱退力
C --------------------------------------------------------------------
C
      READ(10,*) DUM,NENSYU
      IF(NENSYU.NE.'Q') THEN
        WRITE(6,*) '基礎率の種類が違います  Q ',NENSYU
        STOP
      END IF
      READ(10,*)
      DO X=0,115
        READ(10,*) XX,(Q(KS,X,I),I=1,3)
        IF(X .NE. XX) THEN
          WRITE(6,*) '基礎率の年齢が違います Q ',X
          STOP
        END IF
      END DO
C
      IF(KZN.EQ.3 .OR. KZN.EQ.5) THEN
        TMP=0.0D0
      ELSE
        TMP=1.0D0
      END IF
C
      DO 1300 K=KS,KE
        DO 1310 X=0,115
          DO 1320 I=1,3
            IF(I.EQ.3) THEN
              IF(SS.EQ.1) SSS=2
              IF(SS.EQ.2) SSS=1
            ELSE
              SSS=SS
            END IF
            QPR(1)=1.0D0
            QPR(2)=1.0D0
C
            IF(K.LT.KS .AND. Q(KS,X,I).GT.0.0D0) THEN
              IF((I.EQ.3 .AND. X.LT.60 .AND. S.NE.2) .OR.
     &           (I.EQ.3 .AND. X.LE.18)) THEN
                Q(K,X,I)=Q(KS,X,I)
              ELSE
                IF(I.NE.2) THEN
                  IF(X.LE.104) THEN
                    Q(K,X,I)=MAX(QP(SEIY,X,SSS)*TMP,
     &                           QP(K,X,SSS)/QP(KS,X,SSS)*Q(KS,X,I))
                  ELSE
                    Q(K,X,I)=MAX(QP(SEIY,104,SSS)*TMP,
     &                       QP(K,104,SSS)/QP(KS,104,SSS)*Q(KS,X,I))
                  END IF
                ELSE IF(I.EQ.2) THEN
                  IF(Q(KS,X,1).GT.1.0D-6) THEN
                    Q(K,X,I)=MIN(Q(KS,X,I)*Q(K,X,1)/Q(KS,X,1),1.0D0)
                  ELSE
                    Q(K,X,I)=0.0D0
                  END IF
                END IF
              END IF
C
            ELSE IF(Q(KS,X,I).GT.0.0D0) THEN
              IF(I.EQ.3 .AND. X.LT.60) THEN
                Q(K,X,I)=Q(KS,X,I)
              ELSE IF(I.NE.2) THEN
                IF(X.LE.104) THEN
                  Q(K,X,I)=
     &              MAX(QP(SEIY,X,SSS)*QPR(SSS)*TMP,
     &                  MIN(Q(KS,X,I),
     &                      QP(MIN(K,KZNY,SEIY),X,SSS)
     &                        *( (Q(KS,X,I)/QP(KS,X,SSS)
     &                             *DBLE(MAX(SEIY-K,0))
     &                          +DBLE(MIN(K-KS,SEIY-KS))*QPR(SSS) )
     &                                           / DBLE(SEIY-KS) ) ) )
                ELSE
                  IF(Q(KS,104,I).GT.1.0D-6) THEN
                    Q(K,X,I)=MIN(Q(K,104,I)*Q(KS,X,I)/Q(KS,104,I)
     &                           ,1.0D0)
                  ELSE
                    Q(K,X,I)=0.0D0
                  END IF
                END IF
              ELSE IF(I.EQ.2) THEN
                IF(Q(KS,X,1).GT.1.0D-6) THEN
                  Q(K,X,I)=MIN(Q(KS,X,I)*Q(K,X,1)/Q(KS,X,1),1.0D0)
                ELSE
                  Q(K,X,I)=0.0D0
                END IF
              END IF
            ELSE
              Q(K,X,I)=0.0D0
            END IF
C
            Q(K,X,I)=MIN(MAX(Q(K,X,I),0.0D0),1.0D0)
C
            IF(X.EQ.115 .OR. (I.EQ.3 .AND. X.EQ.18) .OR.
     &         (I.EQ.3 .AND. K.EQ.KIJUN+1 .AND. X.EQ.19)) Q(K,X,I)=1.0D0
 1320     CONTINUE
 1310   CONTINUE
 1300 CONTINUE
C
      DO K=KS+1,KE
        Q(K,65,2) =  MAX(0.0D0, DBLE(KS+40-K)/40.0D0) * Q(K,65,2)
     &             + MIN(1.0D0, DBLE(K-KS)/40.0D0)
     &               * (Q(K,64,2)+Q(K,66,2)) / 2.0D0 
      END DO
C
      IF((KZN.EQ.4 .OR. KZN.EQ.5) .AND.
     &   KZNY.GT.KS .AND. KZNY.LE.KE   ) THEN
        DO K=KZNY,KE
          DO X=0,115
            DO I=1,3
                Q(K,X,I)=Q(KZNY-1,X,I)
            END DO
          END DO
        END DO
      END IF
C
      READ(10,*) DUM,NENSYU
      IF(NENSYU.NE.'U') THEN
        WRITE(6,*) '基礎率の種類が違います  U  ',NENSYU
        STOP
      END IF
      READ(10,*)
      IF(KONEN.EQ.1) THEN
        DO X=15,84
          READ(10,*) XX,(U(KS+1,X,I),I=1,3)
          IF(X .NE. XX) THEN
            WRITE(6,*) '基礎率の年齢が違います U ',X
            STOP
          END IF
        END DO
      ELSE
        DO X=15,74
          READ(10,*) XX,(U(KS+1,X,I),I=1,3)
          IF(X .NE. XX) THEN
            WRITE(6,*) '基礎率の年齢が違います U ',X
            STOP
          END IF
        END DO
      END IF
C
C
      RDS(1)=0.07D0
      RDS(2)=0.20D0
      RDSP1(1)=0.00D0
      RDSP1(2)=0.00D0
      RDSP2(1)=0.00D0
      RDSP2(2)=0.00D0
      RDSP3(1)=0.40D0
      RDSP3(2)=0.20D0
C
      IF(PSEID.EQ.1) THEN
C
        DO X=15,85
          U(KS+1,X,0)=U(KS+1,X,1)+U(KS+1,X,2)+U(KS+1,X,3)
        END DO
C
        IF(S.EQ.2) THEN
          TMP = 0.24545D0
        ELSE
          TMP = 0.025D0
        END IF
        DO K=KS+2,KE
          DO X=15,85
            IF      ((K.EQ.17             ) .AND. X.EQ.62) THEN
              U(K,X,0)=U(K-1,X,0)-TMP
            ELSE IF(((K.EQ.18 .OR. K.EQ.19) .AND. X.EQ.63) .OR.
     &              ((K.EQ.21 .OR. K.EQ.22) .AND. X.EQ.64) .OR.
     &              ((K.EQ.24 .OR. K.EQ.25) .AND. X.EQ.65) .OR.
     &              ((K.EQ.27             ) .AND. X.EQ.66)) THEN
              U(K,X,0)=U(K-1,X,0)+TMP
            ELSE
              U(K,X,0)=U(K-1,X,0)
            END IF
          END DO
        END DO
      END IF
C
C
      IF(KZN.EQ.3 .OR. KZN.EQ.5) THEN
        TMP=0.0D0
      ELSE
        TMP=1.0D0
      END IF
C
C
      DO K=KS+1,KE
        BETA(K,15)=-LOG(1.0D0-QP(MIN(K,SEIY),15,SS))
C
        DO X=16,84
          BETA(K,X)=(-LOG(1.0D0-QP(MIN(K,SEIY),X,SS))
     &               -LOG(1.0D0-QP(MIN(K,SEIY),X-1,SS)))/2.0D0
        END DO
      END DO
C
      DO 1130 K=KS+1,KE
        DO 1140 X=15,84
C
          U(K,X,1)=U(KS+1,X,1)
C
          IF(K.LE.KS+1) THEN
            IF(BETA(KS+1,X).GT.1.0D-6) THEN
              U(K,X,3)=MAX(BETA(SEIY,X)*TMP,
     &                     (BETA(K,X)/BETA(KS+1,X))*U(KS+1,X,3))
            ELSE
              U(K,X,3)=0.0D0
            END IF
          ELSE
            IF((KZN.EQ.6 .OR. KZN.EQ.7) .AND. K.GE.KZNY) THEN
              U(K,X,3)=MAX(BETA(SEIY,X)*TMP,BETA(MIN(KZNY,SEIY),X))
            ELSE
C
              U(K,X,3)=U(KS+1,X,3)
            END IF
          END IF
 1140   CONTINUE
 1130 CONTINUE
C
C --------------------------------------------------------------------
C     Ｑ（Ｋ，Ｘ，１）  老齢年金失権率・待期者死亡率
C                 ２    障害年金失権率（死亡者割合込み）
C                 ３    遺族年金失権率
C --------------------------------------------------------------------
C
      DO K=KS+1,KE
        DO X=0,115
          IF(X.GE.70) THEN
            IF(Q(K,X,1).LT.1.0D0-1.0D-6) THEN
              U(K,X,3)=-LOG(1.0D0-Q(K,X,1))
            ELSE
              U(K,X,3)=1000.0D0
            END IF
          END IF
        END DO
      END DO
C
      TMP=(U(KS,59,1)+U(KS,60,1))/2.0D0
      DO 1500 K=KS+1,KE
        DO 1510 X=15,84
C
          IF(S2.LE.3 .AND. KONEN.EQ.1) THEN
            IF(S2.NE.2) THEN
              S3=1
            ELSE
              S3=2
            END IF
            IF(K.GT.KS+1 .AND. K.LE.40) THEN
              U(K,X,1)=U(KS+1,X,1)*(1.0D0-RDS(S3)
     &                  *(DBLE(K-(KS+1))/DBLE(40-(KS+1))))
            ELSE IF(K.GT.40) THEN
              U(K,X,1)=U(K,X,1)*(1.0D0-RDS(S3))
            END IF
            IF(K.GT.PARTYR1 .AND. PSEID.EQ.0) THEN
              IF(FLG_PART.GE.3 .AND. K.GT.PARTYR2 .AND.
     &           X.LE.22+K-PARTYR2                     ) THEN
                U(K,X,1)=U(K,X,1)*(1.0D0-RDSP3(S3))
              ELSE IF(FLG_PART.GE.1 .AND. FLG_PART.LE.2 .AND.
     &                K.GT.PARTYR2 .AND. X.LE.22+K-PARTYR2 ) THEN
                U(K,X,1)=U(K,X,1)*(1.0D0-RDSP2(S3))
              ELSE IF(X.LE.22+K-PARTYR1) THEN
                U(K,X,1)=U(K,X,1)*(1.0D0-RDSP1(S3))
              END IF
            END IF
          END IF
C
          IF(X.LE.64) THEN
            U(K,X,2)=U(KS+1,X,2)
          ELSE
            U(K,X,2)=0.0D0
          END IF
 1510   CONTINUE
 1500 CONTINUE
C
      DO 1600 K=KS+1,KE
        IF(PSEID.EQ.0) THEN
          TMXEND=85
        ELSE
          TMXEND=70
        END IF
C
        DO 1610 X=15,85
C
          CALL SKNR(X,XXR,XRB)
          XRB=MAX(60,XRB)
          IF(KONEN.EQ.1) THEN
            IF(X.GT.XRB) THEN
              U(K,X,1)=0.0D0
            END IF
          END IF
C
          IF(X.GE.TMXEND) U(K,X,1)=1000.0D0
          IF(PSEID.NE.1) THEN
            U(K,X,0)=U(K,X,1)+U(K,X,2)+U(K,X,3)
          END IF
C
          U(K,X,0)=MAX(U(K,X,0),0.0D0)
          U(K,X,2)=MIN(MAX(U(K,X,2),0.0D0),1.0D0)
          U(K,X,3)=MIN(MAX(U(K,X,3),0.0D0),1.0D0-U(K,X,2))
C
          U(K,X,1)=U(K,X,0)-U(K,X,2)-U(K,X,3)
C
 1610   CONTINUE
 1600 CONTINUE
C
C --------------------------------------------------------------------
C     ＲＴ（Ｋ，Ｘ）  再加入者／（新規加入者＋再加入者）
C --------------------------------------------------------------------
C
      READ(10,*) DUM,NENSYU
      IF(NENSYU.NE.'RT') THEN
        WRITE(6,*) '基礎率の種類が違います  RT  '
        STOP
      END IF
      READ(10,*)
      DO X=15,74
        READ(10,*) XX,RT(KS,X)
        IF(X.NE.XX) THEN
          WRITE(6,*) '基礎率の年齢が違います RT ',X
          STOP
        END IF
      END DO
C
      RT(KS,65)=RT(KS,64)
C
      DO X=15,74
        DO K=KS+1,KE
          CALL SKNR(X,XXR,XRB)
          XRB=MAX(60,XRB)
C
          RT(K,X)=RT(KS,X)
          IF(X.GT.XRB) RT(K,X)=0.0D0
        END DO
      END DO
C
      IF(S2.LE.3) THEN
        IF(S2.NE.2) THEN
          S3=1
        ELSE
          S3=2
        END IF
        DO K=KS,KE
          DO X=15,74
            IF(K.GE.KS .AND. K.LT.40) THEN
              RT(K,X)=MIN(1.0D0,RT(K,X)
     &                    *(1.0D0+RDS(S3)*DBLE(K-KS)/DBLE(40-KS)))
            ELSE IF(K.GE.40) THEN
              RT(K,X)=MIN(1.0D0,RT(K,X)*(1.0D0+RDS(S3)))
            END IF
            IF(K.GT.PARTYR2 .AND. PSEID.EQ.0) THEN
              IF(FLG_PART.GE.3 .AND. X.LE.22+K-PARTYR2) THEN
                RT(K,X)=MIN(1.0D0,RT(K,X)*(1.0D0+RDSP3(S3)))
              ELSE IF(FLG_PART.EQ.2 .AND. X.LE.22+K-PARTYR2) THEN
                RT(K,X)=MIN(1.0D0,RT(K,X)*(1.0D0+RDSP2(S3)))
              ELSE IF(FLG_PART.EQ.1 .AND. X.LE.22+K-PARTYR2) THEN
                RT(K,X)=MIN(1.0D0,RT(K,X)*(1.0D0+RDSP1(S3)))
              END IF
            END IF
          END DO
        END DO
      END IF
C
C
C --------------------------------------------------------------------
C     ＹＸ（Ｋ，Ｘ, Ｊ） 年齢相関  被保険者から遺族
C                     S!=2の場合：J=0:被保から妻、
C                     S==2の場合：J=0:被保から夫、J=1:被保から子
C     ＮＳ（Ｋ，Ｘ）  加給・加算用  受給者から配偶者
C --------------------------------------------------------------------
C
      READ(10,*) DUM,NENSYU
      IF(NENSYU.NE.'YX') THEN
        WRITE(6,*) '基礎率の種類が違います  YX  '
        STOP
      END IF
      READ(10,*)
      DO X=15,115
        IF(S.NE.2) THEN
          READ(10,*) XX,YX(KS,X,0),NS(KS,X)
          YX(KS,X,1)=0.0D0
        ELSE
          READ(10,*) XX,YX(KS,X,0),YX(KS,X,1),NS(KS,X)
        END IF
        IF(X.NE.XX) THEN
          WRITE(6,*) '基礎率の年齢が違います YX ',X
          STOP
        END IF
      END DO
C
      DO K=KS+1,KE
        DO X=15,115
          YX(K,X,0)=YX(KS,X,0)
          YX(K,X,1)=YX(KS,X,1)
          NS(K,X)=NS(KS,X)
        END DO
      END DO
C
C
C --------------------------------------------------------------------
C     ＲＣ（Ｓ，Ｋ，Ｘ）  妻の子あり割合
C --------------------------------------------------------------------
C
      READ(10,*) DUM,NENSYU
      IF(NENSYU.NE.'RC') THEN
        WRITE(6,*) '基礎率の種類が違います  RC  '
        STOP
      END IF
      READ(10,*)
      DO 2600 X=15,115
        READ(10,*) XX,RC(S,KS+1,X)
        IF(X.NE.XX) THEN
          WRITE(6,*) '基礎率の年齢が違います RC ',X
          STOP
        END IF
 2600 CONTINUE
C
      DO K=KS+2,KE
        DO X=15,110
          RC(S,K,X)=RC(S,KS+1,X)
        END DO
      END DO
C
      IF(S.EQ.2) THEN
        DO K=KS+2,KE
          DO X=58,115
            IF(K-14.EQ.X-55) THEN
              RC(S,K,X)=RC(S,K-1,X)*(K-13-0.5)/DBLE((K-1)-13)
            ELSE IF(K-14.LT.X-55) THEN
              RC(S,K,X)=RC(S,K-1,X)*(K-13)/DBLE((K-1)-13)
            ELSE 
              RC(S,K,X)=RC(S,K-1,X)
            END IF
          END DO
        END DO
      END IF
C
C
C --------------------------------------------------------------------
C     ＣＬ（Ｋ，１）  障害年金１級割合
C               ２            ２級割合
C               ３            ３級割合
C     ＣＬ２は旧法分
C --------------------------------------------------------------------
C
      READ(10,*) DUM,NENSYU
      IF(NENSYU.NE.'CL') THEN
        WRITE(6,*) '基礎率の種類が違います  CL  '
        STOP
      END IF
      READ(10,*)
      READ(10,*) DUM,(CL(KS,I),I=1,3),(CL2(KS,I),I=1,3)
C
      DO K=KS+1,KE
        DO I=1,3
          CL(K,I) =CL(KS,I)
          CL2(K,I)=CL2(KS,I)
        END DO
      END DO
C
C --------------------------------------------------------------------
C     ＫＤ（Ｋ，Ｉ，Ｊ，Ｘ）  １人当たりの加給年金平均対象者数
C                         Ｉ＝１  新法老齢（ＩＴ＝１，２）
C                             ２  旧法老齢
C                             ３  新法障害
C                             ４  旧法障害
C                             ５  遺族
C                             ６  新法通算老齢
C                         Ｊ＝１  配偶者
C                             ２  子（第１，２子）
C                             ３  〃（第３子以上）
C                             ４  配偶者振替
C                         Ｘ：年齢
C --------------------------------------------------------------------
C
      READ(10,*) DUM,NENSYU
      IF(NENSYU.NE.'KD') THEN
        WRITE(6,*) '基礎率の種類が違います  KD  '
        STOP
      END IF
      READ(10,*)
      READ(10,*)
      DO 3000 X=0,115
        READ(10,*) XX,(KD(KS,I,1,X),I=1,2),(KD(KS,1,J,X),J=2,3),
     &                (KD(KS,I,1,X),I=3,4),(KD(KS,3,J,X),J=2,3),
     &                (KD(KS+1,5,J,X),J=2,3),KD(KS,1,4,X)
        IF(X.NE.XX) THEN 
          WRITE(6,*) '基礎率 KD  年齢が違います',X,XX
          STOP
        END IF
        DO J=2,3
          KD(KS,2,J,X)=KD(KS,1,J,X)
          KD(KS,4,J,X)=KD(KS,3,J,X)
        END DO
        KD(KS,3,4,X)=KD(KS,1,4,X)
 3000 CONTINUE
C
      IF(S.NE.2) THEN
        KDC=0.02701133D0
      ELSE
        KDC=0.00304847D0
      END IF
C
      DO J=1,4
        DO I=1,6
          IF(((I.EQ.2 .OR. I.EQ.4 .OR. I.EQ.5) .AND. J.EQ.4)
     &       .OR. (I.EQ.5 .AND. J.EQ.1)) CYCLE
          DO K=KS,KE
            DO X=0,115
              IF(I.NE.5 .AND. I.NE.6) THEN
                KD(K,I,J,X)=KD(KS,I,J,X)
              ELSE IF(I.EQ.5) THEN
                IF(K.EQ.KS) EXIT
                KD(K,I,J,X)=KD(KS+1,I,J,X)
              ELSE IF(I.EQ.6) THEN
                IF      (K-15.LE.X-64) THEN
                  KDCTMP=KDC*0
                ELSE IF (K-15.EQ.X-63) THEN
                  KDCTMP=KDC*1
                ELSE IF (K-15.EQ.X-62) THEN
                  KDCTMP=KDC*2
                ELSE IF (K-15.EQ.X-61) THEN
                  KDCTMP=KDC*3
                ELSE IF (K-15.EQ.X-60) THEN
                  KDCTMP=KDC*4
                ELSE IF (K-15.GE.X-59) THEN
                  KDCTMP=KDC*5
                END IF
                KD(K,I,J,X)=KD(KS,1,J,X)*KDCTMP
              END IF
            END DO
          END DO
        END DO
      END DO
C
      IF(S.EQ.2) THEN
        DO K=KS+2,KE
          DO X=58,115
           DO J=2,3
            IF(K-14.EQ.X-55) THEN
              KD(K,5,J,X)=KD(K-1,5,J,X)*(K-13-0.5)/DBLE((K-1)-13)
            ELSE IF(K-14.LT.X-55) THEN
              KD(K,5,J,X)=KD(K-1,5,J,X)*(K-13)/DBLE((K-1)-13)
            ELSE 
              KD(K,5,J,X)=KD(K-1,5,J,X)
            END IF
           END DO
          END DO
        END DO
      END IF
C
C---------------------------------------------------------------------
C     ＩＫＵＣＯＥ  育児休業の標準報酬総額の調整係数
C     ＪＩＩＫＵ　　次世代育成支援効果の調整係数
C---------------------------------------------------------------------
C
      READ(10,*) DUM,NENSYU,IKUCOE(KS+1)
      IF(NENSYU.NE.'IK') THEN
        WRITE(6,*) '基礎率の種類が違います  IK  '
        STOP
      END IF
C
      READ(10,*) DUM,NENSYU,TMP
      IF(NENSYU.NE.'SK') THEN
        WRITE(6,*) '基礎率の種類が違います  SK  '
        STOP
      END IF
C
      DO K=KS+2,KE
        IKUCOE(K)=IKUCOE(KS+1)
        IF(FLG_SANKYU.EQ.1 .AND. K.GE.SANKYUYR) THEN
          IKUCOE(K)=IKUCOE(K)+TMP
        END IF
      END DO
C
      READ(10,*) DUM,NENSYU,JIIKU
      IF(NENSYU.NE.'JIIKU') THEN
        WRITE(6,*) '基礎率の種類が違います  JIIKU'
        STOP
      END IF
C
C---------------------------------------------------------------------
C     基礎率の出力
C---------------------------------------------------------------------
C
      IF(NENBEEX.EQ.0) THEN
        WRITE(93,*) '受給者の失権率 Q'
        WRITE(93,*) '記号,種別,年度,年齢,老齢,障害,遺族'
        DO K=KS,KE
          DO X=0,115
            WRITE(93,8000) 'Q',S,K,X,(Q(K,X,I),I=1,3)
          END DO
        END DO
 8000 FORMAT(A,',',3(I3,','),3(E22.15,','))
C
        WRITE(93,*) '被保険者の脱退力 U'
        WRITE(93,*) '記号,種別,年度,年齢,計,生存,障害,死亡'
        DO K=KS+1,KE
          DO X=15,84
            WRITE(93,8010) 'U',S,K,X,(U(K,X,I),I=0,3)
          END DO
        END DO
 8010 FORMAT(A,',',3(I3,','),4(E22.15,','))
C
        WRITE(93,*) '再加入者/(新規加入者+再加入者) RT'
        WRITE(93,*) '記号,種別,年度,年齢,'
     &                //'再加入者/(新規加入者+再加入者)'
        DO K=KS,KE
          DO X=15,74
            WRITE(93,8020) 'RT',S,K,X,RT(K,X)
          END DO
        END DO
 8020 FORMAT(A,',',3(I3,','),E22.15)
C
        WRITE(93,*) '年齢相関 YX'
        WRITE(93,*) '記号,種別,年度,年齢,被保から妻/夫,被保から子'
        DO K=KS,KE
          DO X=15,115
            WRITE(93,8030) 'YX',S,K,X,(YX(K,X,J),J=0,1)
          END DO
        END DO
 8030 FORMAT(A,',',3(I3,','),2(E22.15,','))
C
        WRITE(93,*) '加給・加算用（受給者から配偶者） NS'
        WRITE(93,*) '記号,種別,年度,年齢,'
     &                  //'加給・加算用（受給者から配偶者）'
        DO K=KS,KE
          DO X=15,115
            WRITE(93,8040) 'NS',S,K,X,NS(K,X)
          END DO
        END DO
 8040 FORMAT(A,',',3(I3,','),E22.15)
C
        WRITE(93,*) '有子割合 RC'
        WRITE(93,*) '記号,種別,年度,年齢,有子割合'
        DO K=KS+1,KE
          DO X=0,115
            WRITE(93,8050) 'RC',S,K,X,RC(S,K,X)
          END DO
        END DO
 8050 FORMAT(A,',',3(I3,','),E22.15)
C
        WRITE(93,*) '障害年金割合 CL'
        WRITE(93,*) '記号,種別,年度,年齢,1級,2級,3級'
        DO K=KS,KE
          DO X=0,115
            WRITE(93,8060) 'CL',S,K,X,(CL(K,I),I=1,3)
          END DO
        END DO
 8060 FORMAT(A,',',3(I3,','),3(E22.15,','))
C
        WRITE(93,*) '振替加算割合 KD'
        WRITE(93,*) '記号,種別,年度,年齢,'
     &            //'新老（配）,新老（子12）,新老（子3）,新老（配振）,'
     &            //'旧老（配）,旧老（子12）,旧老（子3）,'
     &            //'新障（配）,新障（子12）,新障（子3）,新障（配振）,'
     &            //'旧障（配）,旧障（子12）,旧障（子3）,'
     &            //           '遺族（子12）,遺族（子3）,'
     &            //'新通（配）,新通（子12）,新通（子3）,新通（配振）,'
        DO K=KS,KE
          DO X=0,115
            WRITE(93,8070) 'KD',S,K,X,
     &                      (KD(K,1,J,X),J=1,4),
     &                      (KD(K,2,J,X),J=1,3),
     &                      (KD(K,3,J,X),J=1,4),
     &                      (KD(K,4,J,X),J=1,3),
     &                      (KD(K,5,J,X),J=2,3),
     &                      (KD(K,6,J,X),J=1,4)
          END DO
        END DO
 8070 FORMAT(A,',',3(I3,','),20(E22.15,','))
C
        WRITE(93,*) '育児休業の標準報酬総額の調整係数 IKUCOE'
        WRITE(93,*) '記号,種別,年度,調整係数'
        DO K=KS+1,KE
          WRITE(93,8080) 'IKUCOE',S,K,IKUCOE(K)
        END DO
        WRITE(93,*) '次世代育成支援効果の調整係数 JIIKU'
        WRITE(93,*) '記号,種別,年度,調整係数'
        DO K=KS+1,KE
          WRITE(93,8080) 'JIIKU',S,K,JIIKU
        END DO
 8080 FORMAT(A,',',2(I3,','),E22.15)
C
      END IF
C
C
      RETURN
C
      END
C